Tippseite

VB-Homepage Tipp 252

Shell32 / systemeigene Verzeichnisauswahl nutzen

Eine Möglichkeit, die systemeigene Verzeichnisauswahl für das eigene Programm zu nutzen, wird Inhalt dieses Tipps sein.

Sie sollten dabei abwägen, ob Sie dies nutzen oder mit dem Dialog Control arbeiten, denn hier müssen Sie einiges mehr definieren, ersparen sich allerdings auch ein zusätzliches Control in Ihrem Programm und diese Art ist auch wesentlich flexibler, da dieser Tipp nur einen Teil der Möglichkeiten wiedergibt.

Für einen Test benötigen Sie lediglich einen Commandbutton auf Ihrer Form, der später die Aktion auslösen wird. Und nun zur Definition.

Allgemein/Deklarationen
Option Explicit

Private Type BrowseInfo
   hWndOwner As Long
   pIDLRoot As Long
   pszDisplayName As Long
   lpszTitle As Long
   ulFlags As Long
   lpfnCallback As Long
   lParam As Long
   iImage As Long
End Type

Private Const BIF_RETURNONLYFSDIRS = 1
Private Const MAX_PATH = 260

Private Declare Function lstrcat Lib "kernel32" Alias "lstrcatA" (ByVal lpString1 As String, ByVal lpString2 As String) As Long
Private Declare Function SHBrowseForFolder Lib "shell32" (lpbi As BrowseInfo) As Long
Private Declare Function SHGetPathFromIDList Lib "shell32" (ByVal pidList As Long, ByVal lpBuffer As String) As Long

Dim sPath As String

Allgemein/BrowseForFolder
Public Function BrowseForFolder(hWndOwner As Long, sPrompt As String) As String

Dim iNull As Integer
Dim lpIDList As Long
Dim lResult As Long
Dim udtBI As BrowseInfo

With udtBI
   .hWndOwner = hWndOwner
   .lpszTitle = lstrcat(sPrompt, "")
   .ulFlags = BIF_RETURNONLYFSDIRS
End With

lpIDList = SHBrowseForFolder(udtBI)

If lpIDList Then
   sPath = String$(MAX_PATH, 0)
   lResult = SHGetPathFromIDList(lpIDList, sPath)
   iNull = InStr(sPath, vbNullChar)

   If iNull Then
      sPath = Left$(sPath, iNull - 1)
   End If
End If

BrowseForFolder = sPath
End Function

Command1/Click
Call BrowseForFolder(0, "")
MsgBox "Gewähltes Verzeichnis ist " & sPath

Starten sie Ihr Projekt mit F5 und klicken sie auf den Commandbutton. Als Rückgabewert erhalten Sie das gewählte Verzeichnis.

Tipp-Download

Quelle :